simulator lang=spectre


// All the parameters that model the capacitance of 
// the varactor and the temperature dependence of it 
// has been copied from the teaching model for TT process. 
// (cj, mj, cjsw, vsjw, msjw, pb, tlev,tlevc)
// 
// imax is chosen arbitarily high as 1e20, so that you will not 
// have any numerical problems during your simulations. This is 
// the parameter sets the maximum current can flow through 
// the varactor.
// 
// ATTENTION !!! 
// IMPORTANT: The area and perimeter of the "dio"(which is the 
// main diode in varactor model) is calculated for L=2 micron, 
// W=5 micron and number of fingers of 30. Thus if you need to 
// have higher capacitance, just put several in paralel. However,
// if you need lower capacitance change the area and  perimeter 
// of models by using the following formulas.
//   
// For model dio
//   area= number of fingers *(2 microns * 5 microns)
//   perim= number of fingers * 2 *(2 microns * 5 microns)
//   
// For model dionw_sub
//   Just multiply the values of "dio" by 2.
//


inline subckt varactor (PLUS MINUS)
diode1 (PLUS MINUS) dio
diode2 (0 MINUS) dionw_sub
ends varactor

model dio diode
+ level=3                   area=3e-10                perim=4.2e-4
+ is=1.2e-07             
+ rs=1e-09                  ik=3e7                  
+ bv=10                     ibv=150		      tnom=27
+ cj=1.165397e-3            mj=0.4212414
+ cjsw=2.042242e-10         mjsw=0.35885597	      
+ pb=0.7342005		    vjsw=0.68
+ cta=0.00104               ctp=6.8e-04
+ pta=1.5e-03               ptp=1.5e-03               
+ tlev=1                    eg=1.17		      xti=3 
+ tlevc=1                   imax=1e20 


model dionw_sub diode
+ level=3                   area=6e-09             perim=8.4e-3
+ is=4.1e-06                isw=3.2e-12         
+ rs=9e-06                  ik=425                 ikp=3.21e+04
+ bv=15                     tnom=27
+ cjo=1.1e-4                mj=0.5
+ cjsw=2.4e-11              mjsw=0.33		   
+ pb=0.75		    vjsw=0.75 
+ tlev=1                    eg=1.17                xti=3
+ tlevc=1 		    imax=1e20